DAD BAT file information
When one click on the DAD icon to start DAD, they are really running a BAT file. This BAT file is typically called DADLOCAL.BAT for running DAD in Local mode or DADNET.BAT for running DAD in a network mode. To view the BAT file, one can Right Click on the icon and select EDIT or Open With Notepad.
The DADNET and DADLOCAL BAT files are very similar. The only real differences between DADLOCAL and DADNET are the following lines:
| LINE | PURPOSE |
| @set data_drive=F: | This line should always be set
to the drive letter where all the shared DAD Data is. Typcially this is F:
for a networked system.
When DAD is running locally (from the local drive only) then this line would be set to C:. |
| @set server= | When one is using a network file server, this line is commonly set to the server name. The information set here will be displayed in the Title bar of the DAD program. |
In a Peer to Peer system and in many Networked Server systems one might have additional lines in the BAT file to map drives to the proper locations.
For example:
@net use F: /delete
@net use G: /delete
@net use F: \\%server%\DATA enco /user:nova /persistent:no
@net use G: \\%server%\AUDIO enco /user:nova /persistent:no
These lines will automatically clear any drive that is currently mapped as F: and G: then remap them to the Server. These lines can vary slightly from system to system with the differences being the Server name and the Share names.
The following is an example of a DADNET.BAT file.
@echo off
@if "%name%"=="" goto error1
@if "%location%"=="" goto error1
@set server=
@set app_drive=C:
@set data_drive=F:
@if not exist %app_drive%\dad\dad.exe goto error2
@if not exist %data_drive%\dad\files\cuts.dbf goto error3
@echo DAD for %location% loading now - please wait...
@%data_drive%
@cd\dad
@%app_drive%\dad\progs\rebuild
@%app_drive%\dad\progs\re-plist
@%app_drive%
@cd\dad
@start dad.EXE -l%data_drive%
@rem start /high dad -l%data_drive%
@rem progs\sleep 20
@rem start /low /D\gateway \gateway\dist-wo -min
@exit
:error1
@echo.
@echo You must have valid NAME and LOCATION variables set to run DAD
@echo with a shared file system.
@echo Please check your SYSTEM/ENVIRONMENT and/or AUTOEXEC.BAT settings
@echo to make sure these variables are UNIQUELY set for each workstation.
@pause
@exit
:error2
@echo.
@echo The DAD application program (dad.exe) does not exist in
@echo the specified %app_drive%\dad subdirectory. Please check the
@echo APP_DRIVE variable set at the top of the DADNET.bat startup program.
@pause
@exit
:error3
@echo.
@echo The DAD cuts library data base (cuts.dbf) does not exist in
@echo the specified %data_drive%\dad\files subdirectory. Please check the
@echo DATA_DRIVE variable set at the top of the DADNET.bat startup program.
@pause
@exit