ENCO TECH NOTE

DATE:  10-30-96

RE:    ES-CNV-M Compression utility

COMPONENTS:  WAV2ATX.EXE
             PCM2MPG.EXE

NOTE: These files convert compression algorithm only, NOT sample rate.
If you are dumping songs from CD into .WAV files, they will be at 44.1
KHz.  Make sure all your other jingles, liners, and commercials are
also recorded at 44.1KHz.  Otherwise, check with the manufacturer of
your CD-to-WAV hardware/software to see if a sample rate conversion is
included on their end.

        To use these conversion utilities, it is best to use a batch
file to do conversions in a walkaway mode, since they take approximately
ten times real time to complete.  The reason for this is the main CPU
must process the compression algorithm, rather than the audio board's
dsp chip.

        Place the WAV2ATX.EXE and PCM2MPG.EXE files along with CONVERT.BAT
somewhere on your PATH so they may be accessed from any directory.  To
execute the batch file, use the following parameters:

convert <wav file> <DAD cut number> [location] [delete wav file]

The extensions default to .WAV for the wave file and .FIL for the DAD
cut.  If no location is specified, the cut will be placed in the current
drive's \cuts subdirectory.

The pcm2mpg executable parameters may be adjusted.  Here, the kilobit per
channel rate is set to 096.  You may set it up to 128 for 44.1KHz or 160
for 48KHz.  The conversion utility automatically senses stereo or mono
input and puts the correct information in the Antex header.

CONVERT.BAT:

@echo off
if "%2"=="" goto no2
if not exist %1.wav goto nofind
wav2atx %1.wav tempfile.wav
pcm2mpg tempfile.wav %3\cuts\%2.fil /Kb=096
del tempfile.wav
if "%4"=="delete" del %1.wav
if "%4"=="DELETE" del %1.wav
if "%4"=="del" del %1.wav
if "%4"=="DEL" del %1.wav
goto complete

:no2
cls
echo WAV to ATX file format conversion.
echo by Electronic Design Associates, V 1.0, Sep 1994.
echo.
echo PCM2MPG, a procedure to convert PCM to MPEG
echo by Electronic Design Associates, V 2.0, May 1995
echo.
echo (C) 1993 Antex Electronics Corp
echo
echo.
echo Batch file useage:
echo.
echo convert [wav file] [DAD cut number] (location) (delete wav file)
echo.
echo example:      convert sears 10054
echo               convert music 24800 G:
echo               convert coke 14300 G: delete
goto end

:nofind
echo.
echo ERROR: Cannot locate %1.wav
goto end

:complete
echo.
echo Completed conversion of %1.wav to %3\cuts\%2.fil

:end
echo.
echo.


You may then CALL this batch file from another batch file with a list
of cuts you wish to convert:

MANYCUTS.BAT:

call convert music2 50400
call convert spot1 09512 G:
call convert burger 32095 G: delete
call convert salon 09513 G: delete
call convert promo 50500